Qt Reference Documentation

fftreal.pro Example File

demos/spectrum/3rdparty/fftreal/fftreal.pro
 include(../../spectrum.pri)

 TEMPLATE = lib
 TARGET   = fftreal

 # FFTReal
 HEADERS  += Array.h \
             Array.hpp \
             DynArray.h \
             DynArray.hpp \
             FFTRealFixLen.h \
             FFTRealFixLen.hpp \
             FFTRealFixLenParam.h \
             FFTRealPassDirect.h \
             FFTRealPassDirect.hpp \
             FFTRealPassInverse.h \
             FFTRealPassInverse.hpp \
             FFTRealSelect.h \
             FFTRealSelect.hpp \
             FFTRealUseTrigo.h \
             FFTRealUseTrigo.hpp \
             OscSinCos.h \
             OscSinCos.hpp \
             def.h

 # Wrapper used to export the required instantiation of the FFTRealFixLen template
 HEADERS  += fftreal_wrapper.h
 SOURCES  += fftreal_wrapper.cpp

 DEFINES  += FFTREAL_LIBRARY

 symbian {
     # Provide unique ID for the generated binary, required by Symbian OS
     TARGET.UID3 = 0xA000E403
     TARGET.CAPABILITY = UserEnvironment
 }

 macx {
     CONFIG += lib_bundle
 } else {
     !symbian: DESTDIR = ../..
 }

 # Install

 sources.files = $$SOURCES $$HEADERS fftreal.pro readme.txt license.txt
 sources.files += bwins/fftreal.def eabi/fftreal.def
 sources.path = $$[QT_INSTALL_DEMOS]/spectrum/3rdparty/fftreal
 INSTALLS += sources
X

Thank you for giving your feedback.

Make sure it is related to this specific page. For more general bugs and requests, please use the Qt Bug Tracker.